<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:atom="http://www.w3.org/2005/Atom" xmlns:media="http://search.yahoo.com/mrss/" version="1.0" exclude-result-prefixes="atom media">

    <xsl:output method="html" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:include href="../../plugins/tenandtwo-xslt-processor/xsl/date.xsl"/>

    <xsl:template match="/">
        <xsl:apply-templates select="//channel"/>
    </xsl:template>

    <xsl:template match="channel">
        <!-- header -->
        <div><xsl:apply-templates select="image"/></div>
        <h3><xsl:value-of disable-output-escaping="yes" select="title"/></h3>

        <!-- body -->
        <xsl:apply-templates select="item"/>

        <!-- footer -->
        <hr size="1"/>
        <div>
            <xsl:text>RSS Feed Updated : </xsl:text>
            <xsl:call-template name="date-format">
                <xsl:with-param name="value" select="pubDate"/>
                <xsl:with-param name="format" select="'Y-m-d h:i A'"/>
            </xsl:call-template>
        </div>
        <div>
            <a target="_blank">
                <xsl:attribute name="href"><xsl:value-of select="link"/></xsl:attribute>
                <xsl:text>Visit Website →</xsl:text>
            </a>
        </div>
    </xsl:template>

    <xsl:template match="item">
        <hr size="1"/>
        <div>
            <xsl:apply-templates select="media:content[1]"/>
        </div>
        <h4>
            <a target="_blank">
                <xsl:attribute name="href"><xsl:value-of select="link"/></xsl:attribute>
                <xsl:value-of disable-output-escaping="yes" select="title"/>
            </a>
        </h4>
        <div>
            <xsl:value-of disable-output-escaping="yes" select="description"/>
        </div>
    </xsl:template>

    <xsl:template match="image">
        <a>
            <xsl:attribute name="target">_blank</xsl:attribute>
            <xsl:attribute name="href"><xsl:value-of select="link"/></xsl:attribute>
            <img>
                <xsl:attribute name="src"><xsl:value-of select="url"/></xsl:attribute>
                <xsl:attribute name="alt"><xsl:value-of select="title"/></xsl:attribute>
            </img>
        </a>
    </xsl:template>

    <xsl:template match="media:content">
        <img>
            <xsl:attribute name="src"><xsl:value-of select="@url"/></xsl:attribute>
<!--             <xsl:attribute name="height"><xsl:value-of select="@height"/></xsl:attribute> -->
<!--             <xsl:attribute name="width"><xsl:value-of select="@width"/></xsl:attribute> -->
        </img>
    </xsl:template>

</xsl:stylesheet><!-- end rss.xsl -->